dotfiles/overlays/default.nix

{ inputs
, ...
}:

{
  nvim-plugins = final: prev: {
    vimPlugins = prev.vimPlugins // {
      rainbow-delimiters-nvim = prev.vimUtils.buildVimPlugin {
        name = "raindow-delimiters.nvim";
        src = inputs.plugin-rainbow-delimiters-nvim;
      };

      undotree-nvim = prev.vimUtils.buildVimPlugin {
        name = "undotree.nvim";
        src = inputs.plugin-undotree-nvim;
      };

      vscoq-nvim = prev.vimUtils.buildVimPlugin {
        name = "vscoq.nvim";
        src = inputs.plugin-vscoq-nvim;
      };

      harpoon1 = prev.vimUtils.buildVimPlugin {
        name = "harpoon";
        src = inputs.plugin-harpoon1;
      };
    };
  };

  discord-screenaudio = final: prev: {
    discord-screenaudio = prev.stdenv.mkDerivation
      rec {
        pname = "discord-screenaudio";
        version = "1.9.1";

        src = inputs.discord-screenaudio;

        nativeBuildInputs = with prev; [
          qt6.wrapQtAppsHook
          cmake
          pkg-config
          qt6.qtbase
          qt6.qtwebengine
        ];

        buildInputs = with prev; [
          pipewire
        ];

        preConfigure = ''
          # version.cmake either uses git tags or a version.txt file to get app version.
          # Since cmake can't access git tags, write the version to a version.txt ourselves.
          echo "${version}" > version.txt
        '';

        passthru.updateScript = prev.nix-update-script { };

        meta = {
          description = "A custom discord client that supports streaming with audio on Linux";
          homepage = "https://github.com/maltejur/discord-screenaudio";
          downloadPage = "https://github.com/maltejur/discord-screenaudio/releases";
          changelog = "https://github.com/maltejur/discord-screenaudio/releases/tag/v${version}";
          # license = lib.licenses.gpl3Only;
          # maintainers = with lib.maintainers; [ huantian ];
          # platforms = lib.platforms.linux;
        };
      };
  };
}