DTweaks/build.gradle.kts

import org.jetbrains.kotlin.gradle.tasks.KotlinCompile

plugins {
    kotlin("jvm") version "1.8.22"
    id("com.github.johnrengelman.shadow") version "8.1.1"
    id("xyz.jpenilla.run-paper") version "2.1.0" // Adds runServer and runMojangMappedServer tasks for testing
    id("io.papermc.paperweight.userdev") version "1.5.5"
}

group = "nl.kallestruik"
version = "1.1"

repositories {
    mavenCentral()
    mavenLocal()

    maven("https://papermc.io/repo/repository/maven-public/")
    maven("https://repo.aikar.co/content/groups/aikar/")
    maven("https://repo.dmulloy2.net/repository/public/")
    maven("https://git.kallestruik.nl/api/packages/mc/maven/")
}

dependencies {
    paperweight.paperDevBundle("1.20-R0.1-SNAPSHOT")

    implementation("co.aikar:acf-paper:0.5.1-SNAPSHOT")
    compileOnly("com.comphenix.protocol:ProtocolLib:5.0.0")

    compileOnly("nl.kallestruik:DLib:1.5.1")

    testImplementation(kotlin("test-junit5"))
    testImplementation("org.junit.jupiter:junit-jupiter-api:5.6.0")
    testRuntimeOnly("org.junit.jupiter:junit-jupiter-engine:5.6.0")
}

tasks.build {
    dependsOn(tasks.shadowJar)
}

tasks {
    assemble {
        dependsOn(reobfJar)
    }

    test {
        useJUnitPlatform()
    }

    shadowJar {
        relocate("co.aikar.commands", "nl.kallestruik.dtweaks.acf")
        relocate("co.aikar.locales", "nl.kallestruik.dtweaks.locales")
    }

    compileJava {
        options.compilerArgs.add("-parameters")
    }
    compileKotlin {
        kotlinOptions.javaParameters = true
    }
    withType<KotlinCompile> {
        kotlinOptions.jvmTarget = "17"
    }

    processResources {
        expand("version" to project.version)
    }
}