import org.jetbrains.kotlin.gradle.tasks.KotlinCompile

plugins {
    kotlin("jvm") version "1.5.31"
    id("com.github.johnrengelman.shadow") version "5.2.0"
    id("io.papermc.paperweight.userdev") version "1.3.4"
}

group = "nl.kallestruik"
version = "1.0"

repositories {
    mavenCentral()
    mavenLocal()

    maven("https://papermc.io/repo/repository/maven-public/")
    maven("https://repo.aikar.co/content/groups/aikar/")
    maven("https://repo.dmulloy2.net/repository/public/")
}

dependencies {
    implementation("co.aikar:acf-paper:0.5.0-SNAPSHOT")
    paperDevBundle("1.18.1-R0.1-SNAPSHOT")
    compileOnly("com.comphenix.protocol:ProtocolLib:4.6.0")
    compileOnly(kotlin("stdlib-jdk8"))

    compileOnly("nl.kallestruik:DLib:1.3.5")

    testImplementation(kotlin("test-junit5"))
    testImplementation("org.junit.jupiter:junit-jupiter-api:5.6.0")
    testRuntimeOnly("org.junit.jupiter:junit-jupiter-engine:5.6.0")
}

tasks.shadowJar {
    relocate("co.aikar.commands", "nl.kallestruik.dtweaks.acf")
    relocate("co.aikar.locales", "nl.kallestruik.dtweaks.locales")
}

tasks.build {
    dependsOn(tasks.shadowJar)
}

tasks {
    assemble {
        dependsOn(reobfJar)
    }

    test {
        useJUnitPlatform()
    }

    compileJava {
        options.compilerArgs.add("-parameters")
    }
    compileKotlin {
        kotlinOptions.javaParameters = true
    }
    withType<KotlinCompile> {
        kotlinOptions.jvmTarget = "11"
    }

    processResources {
        expand("version" to project.version)
    }
}